WSUB parameterization
- Kai Zhang
Background
Ice cloud formation is very sensitive to the updraft velocity.
The characteristic updraft velocity for ice nucleation (w*) in the original ACME/CAM5 is parameterized a function of TKE and has an artificial upper bound of 0.2 m/s.
Based on parcel model simulations and in-situ aircraft measurements, we proposed a new treatment of w*, assuming the subgrid variation of vertical velocities follows the Gaussian distribution.
It has been implemented and tested in ACME, along with other improvements for ice cloud parameterizations.
Method
A new sub-grid parameterization of the characteristic updraft velocity (w*) for ice nucleation was proposed by Zhang et al. (in preparation). It is calculated by averaging the vertical velocities in the updraft portion of an assumed sub-grid distribution. In the present scheme, the subgrid variation of vertical velocities is assumed to follow the Gaussian distribution. The upper bound (0.2 m/s) in the original model was removed.
Implementation
A new subroutine is added in nucleate_ice_cam.F90:
subroutine subgrid_mean_updraft(ncol, w0, wsig, ww)
!! interface
integer, intent(in) :: ncol ! number of cols
real(r8), intent(in) :: wsig(pcols,pver ) ! standard deviation (m/s)
real(r8), intent(in) :: w0(pcols,pver ) ! large scale vertical velocity (m/s)
real(r8), intent(out):: ww(pcols,pver) ! mean updraft velocity(m/s) -> characteristic w*
!! local
integer, parameter :: nbin = 50
real(r8) :: wlarge,sigma
real(r8) :: xx, yy
real(r8) :: zz(nbin)
real(r8) :: wa(nbin)
integer :: kp(nbin)
integer :: i, k
integer :: ibin
!! program begins
do k = 1, pver
do i = 1, ncol
sigma = max(0.001_r8, wsig(i,k))
wlarge = w0(i,k)
xx = 6._r8 * sigma / nbin
do ibin = 1, nbin
yy = wlarge - 3._r8*sigma + 0.5*xx
yy = yy + (ibin-1)*xx
!! wbar = integrator < w * f(w) * dw >
zz(ibin) = yy * exp(-1.*(yy-wlarge)**2/(2*sigma**2))/(sigma*sqrt(2*pi))*xx
end do
kp(:) = 0
wa(:) = 0._r8
where(zz.gt.0._r8)
kp = 1
wa = zz
elsewhere
kp = 0
wa = 0._r8
end where
if(sum(kp).gt.0) then
!! wbar = integrator < w * f(w) * dw >
ww(i,k) = sum(wa)
else
ww(i,k) = 0._r8
end if
!!write(6,*) 'i, k, w0, wsig, ww : ', i, k, w0(i,k), wsig(i,k), ww(i,k)
end do
end do
end subroutine subgrid_mean_updraft
Results
Comparison between the parameterized w* and the inverted “true” w* derived from parcel model simulations and aircraft measurements.
Changes in longwave cloud forcing caused by using the new parameterization.
It has a large impact on instantaneous ice nucleation events, but the change to the global annual mean cloud forcing is rather small.